Apex Stem 導入ガイド

List<Account> accounts = [
  SELECT Id, Name, Industry
  FROM Account
  WHERE Industry = :industry
];

Scribe accountScribe = Scribe.of(Account.class)
  .field('Id')
  .field('Name')
  .field('Industry')
  .whereEqual('Industry', industry);
 
List<IEntry> accountEntries = new Eloquent().get(accountScribe);

for(IEntry accountEntry : accountEntries) {
  Id id = accountEntry.getId();                       // 専用 getter
  String name = accountEntry.getName();               // 専用 getter
  String industry = (String) accountEntry.get('Industry'); // キャスト必須
}

// ❌ この items を受け取ったメソッドが未 SELECT の項目を触っても、null が返るだけで静かに通る
List<EstimateItems__c> items = (List<EstimateItems__c>) eloquent.getAsSObject(scribe);
 
// ✅ IEntry のまま渡せば、未 SELECT のアクセスはその場で例外になる
List<IEntry> items = eloquent.get(scribe);

public with sharing class CopyAccountIndustryToOpportunityUsecase {
  @TestVisible static final String LBL_FETCH = 'oppFetch';
  @TestVisible static final String LBL_UPDATE = 'oppUpdate';
 
  private final Set<Id> opportunityIds;
  private final IEloquent eloquent;
  private Trace t = Trace.of('商談に親取引先の業種をコピー');
 
  // public コンストラクタ: 本番用、業務入力だけを受け取る
  public CopyAccountIndustryToOpportunityUsecase(Set<Id> opportunityIds) {
    this(opportunityIds, null);
  }
 
  // private (@TestVisible) コンストラクタ: テストで IEloquent を注入
  @TestVisible
  private CopyAccountIndustryToOpportunityUsecase(
    Set<Id> opportunityIds,
    IEloquent eloquent
  ) {
    this.opportunityIds = opportunityIds;
    this.eloquent = eloquent ?? new Eloquent();
  }
 
  public void invoke() {
    this.t.start();
 
    if(this.opportunityIds == null || this.opportunityIds.isEmpty()) {
      this.t.skip('対象の商談がないため終了。');
      return;
    }
 
    // 商談と、親取引先の業種を一緒に取得
    Scribe oppScribe = Scribe.of(Opportunity.class)
      .field('Id')
      .parentField(Scribe.asParent('AccountId').field('Industry'))
      .whereIn('Id', this.opportunityIds);
 
    List<IEntry> oppEntries = this.eloquent.label(LBL_FETCH).get(oppScribe);
 
    // 各商談に、親取引先の業種をコピー
    for(IEntry oppEntry : oppEntries) {
      IEntry accountEntry = oppEntry.getParent('AccountId');
      oppEntry.put('Industry__c', accountEntry.get('Industry'));
    }
 
    this.eloquent.label(LBL_UPDATE).doUpdate(oppEntries);
 
    this.t.finish(oppEntries.size() + ' 件の商談に業種をコピー。');
  }
}

@isTest
static void testInvoke_WhenOpportunityHasAccount_ThenIndustryCopied() {
  Trace t = Trace.of('正常系: 商談に親取引先の業種がコピーされること');
  t.start();
 
  // Arrange: 親取引先 (業種 = Technology) を持つ商談を 1 件モック
  MockEntry oppEntry = MockEntry.of(Opportunity.class)
    .alias('opp')
    .autoId(1)
    .setParent('AccountId',
      MockEntry.of(Account.class).set('Industry', 'Technology'));
  Id oppId = oppEntry.getAliasId('opp');
  Set<Id> oppIds = new Set<Id>{ oppId };
 
  MockEloquent mock = (new MockEloquent())
    .attach(CopyAccountIndustryToOpportunityUsecase.LBL_FETCH, new List<IEntry>{ oppEntry });
 
  // Act
  (new CopyAccountIndustryToOpportunityUsecase(oppIds, mock)).invoke();
 
  // Assert: 商談に業種がコピーされていること
  List<SObject> updated = mock.upsertedRecordsAt(CopyAccountIndustryToOpportunityUsecase.LBL_UPDATE);
  Assert.areEqual(1, updated.size());
  Assert.areEqual('Technology', ((Opportunity) updated[0]).Industry__c);
  Assert.isTrue(TraceFlow.isLastFinish());
 
  t.finish();
}
 
@isTest
static void testInvoke_WhenNoOpportunityIds_ThenSkipped() {
  Trace t = Trace.of('正常系: 対象の商談がないときスキップされること');
  t.start();
 
  // Arrange
  Set<Id> oppIds = new Set<Id>();
  MockEloquent mock = new MockEloquent();
 
  // Act
  (new CopyAccountIndustryToOpportunityUsecase(oppIds, mock)).invoke();
 
  // Assert
  Assert.isTrue(TraceFlow.isLastSkip());
 
  t.finish();
}

trigger Opportunity on Opportunity(
  before insert, before update, before delete,
  after insert, after update, after delete, after undelete
) {
  (new TriggerOppHandler()).execute();
}

public with sharing class TriggerOppHandler extends TriggerHandler {
  protected override void afterInsert(Map<Id, SObject> newRecordsMap) {
    (new CopyAccountIndustryToOpportunityUsecase(newRecordsMap.keySet())).invoke();
  }
}

@isTest
static void testAfterInsert_WhenOpportunityInserted_ThenIndustryCopied() {
  Trace t = Trace.of('正常系: 商談を insert すると親取引先の業種がコピーされること');
  t.start();
 
  // Arrange: ApexBlueprint で業種を持つ取引先と、その子商談を階層構造で組み立てる
  SOrchestrator orchestrator = SOrchestrator.start()
    .add(SBlueprint.of(Account.class)
      .alias('acc')
      .template(Blueprints.accBasic())
      .set('Industry', 'Technology')
      .withChildren(
        SBlueprint.of(Opportunity.class)
          .alias('opp')
          .template(Blueprints.oppBasic())
      ));
 
  // Act: create() で取引先 → 商談の順に insert され、商談 insert 時に Trigger が発火する
  Test.startTest();
  orchestrator.create();
  Test.stopTest();
 
  // Assert: 商談に親取引先の業種がコピーされていること
  Opportunity opp = (Opportunity) orchestrator.getByAlias('opp');
  Opportunity refetched = [
    SELECT Id, Industry__c
    FROM Opportunity
    WHERE Id = :opp.Id
  ];
  Assert.areEqual('Technology', refetched.Industry__c);
 
  t.finish();
}

// Arrange の階層に times() を足して量産し、
SBlueprint.of(Opportunity.class).template(Blueprints.oppBasic()).alias('opp_{#}').times(30)
 
// Assert に「ガバナ余白」を足す
Assert.isTrue(
  Limits.getQueries() < Limits.getLimitQueries() / 2,
  'バルクでも SOQL は上限の半分未満であること。実測 ' + Limits.getQueries()
);